Repository navigation
Expand file tree
/
Copy pathmodules.cmake
More file actions
142 lines (134 loc) · 7.94 KB
/
Copy pathmodules.cmake
File metadata and controls
142 lines (134 loc) · 7.94 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
# Named modules for tests/language/modules/ (issue #55), included from
# tests/CMakeLists.txt after the per-area test executables exist.
#
# The module units in units/ are built into cppdocs_modules with
# FILE_SET CXX_MODULES; the *_test.cpp files that import them are scanned.
# What can't be built here makes the tests skip with the reason, via
# CPPDOCS_NAMED_MODULES_SKIP / CPPDOCS_IMPORT_STD_SKIP.
set(_mod_dir ${CMAKE_CURRENT_SOURCE_DIR}/language/modules)
set(_mod_tests
${_mod_dir}/modules_test.cpp
${_mod_dir}/building_test.cpp)
# --- Can this configuration build named modules? (cmake-cxxmodules(7)) -----
set(_skip "")
if(CMAKE_VERSION VERSION_LESS 3.28)
set(_skip "CMake ${CMAKE_VERSION} has no FILE_SET CXX_MODULES (needs 3.28)")
elseif(NOT CMAKE_GENERATOR MATCHES "^Ninja")
set(_skip "generator '${CMAKE_GENERATOR}': this suite builds modules with Ninja only")
elseif(CMAKE_CXX_COMPILER_ID STREQUAL "AppleClang")
set(_skip "Apple Clang ${CMAKE_CXX_COMPILER_VERSION}: no clang-scan-deps, so CMake can't scan it for modules")
elseif(CMAKE_CXX_COMPILER_ID STREQUAL "GNU" AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS 14)
set(_skip "GCC ${CMAKE_CXX_COMPILER_VERSION}: CMake scans modules with GCC 14 and newer")
elseif(CMAKE_CXX_COMPILER_ID STREQUAL "GNU" AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS 15
AND CMAKE_SYSTEM_NAME STREQUAL "FreeBSD" AND CMAKE_SYSTEM_VERSION VERSION_GREATER_EQUAL 15)
# Compiler bug: pkg GCC 14.2 on FreeBSD 15.1 segfaults (internal compiler error) on every
# module unit; the same GCC on FreeBSD 14.5 builds them (run 41380889279, #209).
set(_skip "GCC ${CMAKE_CXX_COMPILER_VERSION} on FreeBSD ${CMAKE_SYSTEM_VERSION}: internal compiler error (segfault) on every module unit (issue 209)")
elseif(CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS 16)
set(_skip "Clang ${CMAKE_CXX_COMPILER_VERSION}: CMake scans modules with Clang 16 and newer")
elseif(CMAKE_CXX_COMPILER_ID STREQUAL "Clang" AND NOT CMAKE_CXX_SIMULATE_ID STREQUAL "MSVC"
AND NOT CMAKE_CXX_COMPILER_CLANG_SCAN_DEPS)
# apt.llvm.org ships clang-scan-deps-N in clang-tools-N, not with clang-N;
# without it every scan step fails at build time.
set(_skip "Clang ${CMAKE_CXX_COMPILER_VERSION}: clang-scan-deps not found (install clang-tools), so CMake can't scan it for modules")
elseif(NOT CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang|MSVC")
set(_skip "compiler ${CMAKE_CXX_COMPILER_ID}: CMake can't scan it for modules")
endif()
# No "#" in a reason: CMake drops or mangles a compile definition holding one.
if(_skip)
set_property(TARGET examples_language_tests APPEND PROPERTY
COMPILE_DEFINITIONS "CPPDOCS_NAMED_MODULES_SKIP=\"${_skip}\""
"CPPDOCS_IMPORT_STD_SKIP=\"${_skip}\"")
message(STATUS "tests/language/modules: named modules off: ${_skip}")
return()
endif()
set(_units ${_mod_dir}/units)
add_library(cppdocs_modules STATIC)
target_sources(cppdocs_modules
PRIVATE
${_units}/math.cpp # implementation units: ordinary sources
${_units}/geo.cpp
${_units}/counter.cpp
PUBLIC
FILE_SET CXX_MODULES BASE_DIRS ${_units} FILES
${_units}/math.cppm
${_units}/shapes.cppm
${_units}/config.cppm
${_units}/geo-types.cppm # every partition provides a BMI,
${_units}/geo-ops.cppm # so internal ones go here too
${_units}/geo-detail.cppm
${_units}/geo.cppm
${_units}/counter.cppm
${_units}/token.cppm
${_units}/base.cppm
${_units}/wrapper.cppm)
# The top-level cmake_minimum_required(3.25) leaves CMP0155 OLD, so ordinary
# sources aren't scanned by default: opt in for the implementation units and
# for the tests that import modules.
set_property(TARGET cppdocs_modules PROPERTY CXX_SCAN_FOR_MODULES ON)
set_source_files_properties(${_mod_tests} PROPERTIES CXX_SCAN_FOR_MODULES ON)
# The private module fragment: Clang (and clang-cl) and MSVC (since VS 2019
# 16.8) implement it; GCC 15 and 16 say "sorry, unimplemented: private module
# fragment". Every compiler that skips it gets its own reason (#228).
if(CMAKE_CXX_COMPILER_ID MATCHES "Clang|MSVC")
target_sources(cppdocs_modules PUBLIC FILE_SET CXX_MODULES FILES ${_units}/tally.cppm)
set_property(TARGET examples_language_tests APPEND PROPERTY
COMPILE_DEFINITIONS CPPDOCS_PRIVATE_MODULE_FRAGMENT)
else()
if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
set(_pmf_skip "GCC ${CMAKE_CXX_COMPILER_VERSION}: private module fragment not implemented (sorry, unimplemented)")
else()
set(_pmf_skip "${CMAKE_CXX_COMPILER_ID} ${CMAKE_CXX_COMPILER_VERSION}: private module fragment not built for this compiler")
endif()
set_property(TARGET examples_language_tests APPEND PROPERTY
COMPILE_DEFINITIONS "CPPDOCS_PRIVATE_MODULE_FRAGMENT_SKIP=\"${_pmf_skip}\"")
endif()
# A BMI and its importers must be compiled with the same flags: where
# FindThreads uses -pthread, tests/CMakeLists.txt adds it to every target.
target_link_libraries(examples_language_tests PRIVATE cppdocs_modules)
set_property(TARGET examples_language_tests APPEND PROPERTY
COMPILE_DEFINITIONS CPPDOCS_NAMED_MODULES)
# --- import std ---------------------------------------------------------
# CMake 4.5 provides std to every scanned C++20+ source (but needs GCC 16 on
# macOS: libstdc++ 15 lacks the std module initializer there). CMake 3.30-4.4
# need the experimental gate set before project() (top-level CMakeLists.txt)
# and CXX_MODULE_STD on the target; CMAKE_CXX_COMPILER_IMPORT_STD lists the
# standards the toolchain supports.
set(_std_skip "")
set(_std_level ${CMAKE_CXX_STANDARD})
if(CMAKE_VERSION VERSION_GREATER_EQUAL 4.5)
if(APPLE AND CMAKE_CXX_COMPILER_ID STREQUAL "GNU" AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS 16)
set(_std_skip "CMake ${CMAKE_VERSION}: import std needs GCC 16 or newer on macOS")
endif()
elseif(NOT DEFINED CMAKE_EXPERIMENTAL_CXX_IMPORT_STD)
set(_std_skip "CMake ${CMAKE_VERSION}: import std is experimental before 4.5, and the top-level CMakeLists.txt sets the gate only for 4.3 and 4.4 (the versions tested)")
elseif(CMAKE_CXX_STDLIB_MODULES_JSON AND NOT (IS_ABSOLUTE "${CMAKE_CXX_STDLIB_MODULES_JSON}"
AND EXISTS "${CMAKE_CXX_STDLIB_MODULES_JSON}"))
# The compiler's -print-file-name didn't find the file (Homebrew LLVM keeps
# libc++.modules.json in lib/c++/), and CMake would fail at generate time.
set(_std_skip "${CMAKE_CXX_COMPILER_ID} ${CMAKE_CXX_COMPILER_VERSION}: '${CMAKE_CXX_STDLIB_MODULES_JSON}' not found; pass -DCMAKE_CXX_STDLIB_MODULES_JSON=<path> to build import std")
elseif(NOT _std_level IN_LIST CMAKE_CXX_COMPILER_IMPORT_STD)
string(REPLACE ";" "," _levels "${CMAKE_CXX_COMPILER_IMPORT_STD}") # no ';' in a definition
set(_std_skip "CMake ${CMAKE_VERSION} with ${CMAKE_CXX_COMPILER_ID} ${CMAKE_CXX_COMPILER_VERSION}: no import std for C++${_std_level} (CMAKE_CXX_COMPILER_IMPORT_STD='${_levels}')")
endif()
if(_std_skip)
set_property(TARGET examples_language_tests APPEND PROPERTY
COMPILE_DEFINITIONS "CPPDOCS_IMPORT_STD_SKIP=\"${_std_skip}\"")
message(STATUS "tests/language/modules: import std off: ${_std_skip}")
else()
add_library(cppdocs_modules_std STATIC)
target_sources(cppdocs_modules_std PUBLIC
FILE_SET CXX_MODULES BASE_DIRS ${_units} FILES
${_units}/stdlib_demo.cppm
${_units}/stdcompat_demo.cppm)
# CMake 4.5 provides std only to targets with CXX_SCAN_FOR_MODULES on; with
# CMP0155 OLD a module file set alone isn't enough (seen with 4.5.0-rc2).
set_property(TARGET cppdocs_modules_std PROPERTY CXX_SCAN_FOR_MODULES ON)
if(CMAKE_VERSION VERSION_LESS 4.5)
set_property(TARGET cppdocs_modules_std examples_language_tests PROPERTY CXX_MODULE_STD ON)
endif()
target_link_libraries(examples_language_tests PRIVATE cppdocs_modules_std)
set_property(TARGET examples_language_tests APPEND PROPERTY
COMPILE_DEFINITIONS CPPDOCS_IMPORT_STD)
message(STATUS "tests/language/modules: import std on")
endif()